PD ROM 1/PD ROM Volume I - Macintosh Software from BMUG (1988).iso/Telecommunications/WWIV Mac BBS/BBS Sample Source/modifyseclev.lsp

Text File | 1987-06-21 | 16.6 KB | 549 lines | [TEXT/PJMM]

{ BBS Utility program and documentation for all major BBS files }
{ Modify SecLev file - T R Teague - 17 Oct 86 }
{ This version works under LightSpeed Pascal }
{ modified for version 1.1 of WWIV Mac BBS - T R Teague - 1 Jan 87 }
{ modified for version 2.0 of WWIV Mac BBS - T R Teague - 22 Mar 87 }
{ modified for version 2.2 of WWIV Mac BBS - T R Teague - 25 May 87 }

PROGRAM ModifySecLev;

{ Standard const's, types, vars for BBS files }

    CONST
        strlen = 160; { length of string }

        { added - TRT - 25 May 87 }
        { user-modifable resources }

        StrID = 1000;
         NumStrItems = 5;

        DLoadsStrID = 1001;
        MsgsStrID = 1002;
         numcomptypes = 11; { added for 2.2 - TRT - 21 Jun 87 }

    TYPE
        strtype = STRING[strlen]; { string type }

{ enumerated list of user restrictions }
{ }
{  logons 2/day ('L'), no chatting ('C'), unvalidated messages ('V'), no backspacing ('B'),}
{  can't change automsg/add to BBS list ('A'), can't post anonymous msgs ('*'),}
{  can't post at all ('P'), can't send send E-Mail ('E'), can't vote ('K'),}
{  can't auto-delete msgs ('M')}
{}
        restrictions = (rlogon, rchat, rvalidate, rbackspace, ramsg, rpostan, rpost, remail, rvoting, rmsg);

        acrq = '@'..'G'; { board access : none, A -> G - not really used }

{ emunerated user defaults : spinning cursor, onekey input, word wrap, screen pause }
        deflts = (spcsr, onekey, wordwrap, pause);

{ emunerated anon msg board types : no, yes, forced, dearabby }
        anontyp = (no, yes, forced, dearabby);

{ enumerated security level types : can post, can E-Mail, can post anonymously, }
{  can see anon names on msgs,  co-sysop, limited co-sysop }
        ansttype = (postn, emailn, pana, sanm, cosysop, lcosysop);

{ enumerated special user alerts : alert, can't ???, can't receive E-Mail }
        opts = (myalert, smw, nomail);

        { modified for version 1.1 & 2.0 }
        pnr = RECORD { phone no. info - for sysop's mini-terminal }
                name : STRING[39]; { name of BBS service }
                            number:STRING[32]; { phone no. }
                hs : byte; { baud rate - 300/1200/2400/9600 }
            END;
        slr = RECORD { security level info }
                ttime : byte; { max. no. of mins allowed on }
                mallowed : integer; { max. no. of msgs allowed to be read }
                emails, posts : byte; { max. no. of E-Mail and msgs to be posted }
                anst : SET OF ansttype; { set of security level types  - see above }
            END;
        messages = RECORD { msgs filename info  - e.g filename of form A-32767.1 }
                ltr : char; { board letter (i.e. A = board no. 1) }
                number : integer; { unique msg number }
                ext : byte; { unique msg number for filename extension (MS-DOS) }
            END;
        smalrec = RECORD { names list of users }
                name : STRING[25]; { alias }
                number : integer; { user no. }
            END;
        userrec = RECORD { user info }
                name : STRING[25]; { alias }
                realname : STRING[14]; { realname }
                deleted : boolean; { deleted flag }
                pw : STRING[8]; { password }
                ph : STRING[12]; { phone no. }
                waiting : byte; { no. of E-Mail msgs waiting }
                laston : STRING[10]; { last on date }
                loggedon : integer; { total no. of times logged on system }
                msgpost : integer; { total no. of msgs posted }
                emailsent : integer; { total no. of E-Mail msgs sent }
                feedback : integer; { total no. of feedback msgs sent }
                linelen : byte; { user's screen width }
                pagelen : byte; { user's screen height }
                defaults : SET OF deflts; { set of user defaults (on/off) - see above }
                ontoday : byte; { no. of times logged on today }
                illegal : byte; { no. of illegal logons today }
                cursor : STRING[10]; { spinning cursor (if any) "word" }
                sl : byte; { security level }
                ac : SET OF restrictions; { set of user restrictions (on/off) - see above }
                ar : SET OF acrq; { set of boards user has access to (on/off) - not really used - see above }
                qscan : ARRAY[1..19] OF messages; { last msg Q-scanned for each 1 of 19 possible boards }
                qscn : ARRAY[1..19] OF boolean; { configured Q-Scan flags for up to 19 boards }
                macro : ARRAY[1..2] OF STRING[79]; { control-d & control-f macro expansions }
                comptype : byte; { computer type (1 -> numcomptypes) as set up elsewhere }
                option : SET OF opts; { set of user options (on/off) - see above }
                vote : ARRAY[1..9] OF byte; { voted flags for up to 9 questions }
                sbn : byte; { "special board no." - user has rights to validate/delete msgs on board (0 = All) }
                dsl : byte; { download security level }
                uploads, downloads : integer; { No. of files uploaded/downloaded }
                uk, dk : integer; { No. of Kb's uploaded/downloaded }
            END;
        boardrec = RECORD { msg board info }
                name : STRING[25]; { board title }
                filename : STRING[12]; { name of file used to hold msgs info }
                sl : byte; { min. security level needed to access this board }
                maxmsgs : byte; { max. no. of msgs allowed on this board }
                pw : STRING[10]; { board password (if any) }
                anonymous : anontyp; { type of anonymous access to this board - see above }
                ar : acrq; { access required for this board (not really used) - see above }
                key : char; { character required to reach this board - i.e. 1 -> 19, or this char }
            END;
        msgstat = (validated, unvalidated, deleted); { enumerated msg types - validated, unvalidated, deleted }
        messagerec = RECORD { msgs info }
                title : STRING[30]; { title of msg }
                messagestat : msgstat; { msg type - see above }
                message : messages; { msg filename info - see above }
                owner : integer; { user no. of sender }
                date : integer; { date posted }
                mage : byte; { message age in days }
            END;
        systatrec = RECORD { status record }
                boardpw : STRING[8]; { closed board password (if any) }
                sysoppw : STRING[8]; { sysop's 2nd password }
                hmsg : messages; { msg filename info - next avail. msg filename ??? }
                users : integer; { no. of users currently on system }
                lastdate : STRING[8]; { last date that system was used }
                callernum : integer; { current/next caller no. }
                activetoday : integer; { amount of time in mins that system was up }
                callstoday : integer; { no. of calls today }
                msgposttoday : integer; { no. of msgs posted today }
                emailtoday : integer; { no. of E-Mail msgs sent today }
                fbacktoday : integer; { no. of Feedback msgs sent today }
                uptoday : integer; { no. of uploads today }
                closedsystem : boolean; { closed system flag }
            END;
        mailrec = RECORD { E-Mail info }
                title : STRING[30]; { title of msg }
                from, destin : integer; { user no. of sender, recipient }
                msg : messages; { msg filename info - see above }
                date : integer; { date sent }
                mage : byte; { message age in days }
            END;
        gft = RECORD { G-Files info }
                num : integer; { section no. }
                title : STRING[40]; { G-File title }
                filen : STRING[12]; { G-File filename }
            END;
        charfil = text; { character file type }
        smr = RECORD { small msg info }
                msg : strtype; { the msg }
                destin : integer; { user no. of recipient }
            END;
        vdatar = RECORD { voting data info }
                question : STRING[79]; { question }
                numa : integer; { no. of answers }
                answ : ARRAY[0..9] OF RECORD { 10 possible answers }
                        ans : STRING[25]; { answer }
                        numres : integer; { number of users voting this answer }
                    END;
            END;
        ulrec = RECORD { file section board data }
                name : STRING[25]; { name of board }
                filename : STRING[12]; { name of file that holds file section data }
                password : STRING[10]; { board password (if any) }
                dsl : byte; { min. security level needed to access this board }
                maxfiles : integer; { max. no. of files allowed in this board }
            END;
        ulfrec = RECORD { uploaded file info }
                filename : STRING[12]; { filename }
                description : STRING[60]; { description }
                {res : ARRAY[1..17] OF byte;} { reserved ??? }
                realname : STRING[64]; { added for version 1.1 - MacBinary filename }
                ft : ARRAY[1..3] OF byte; { filetype - not really used (MS-DOS) }
                blocks : integer; { size in blocks }
                owner : integer; { user no. of uploader }
                date : STRING[8]; { date uploaded }
                daten : integer; { day no. of the year when uploaded }
                numdloads : integer; { added for version 1.1 }
            END;

    VAR
    { file vars for different types of files }
 { nested comments not allowed in LSP }

        sf : FILE OF smalrec; { filename = gfiles\names.lst }
        uf : FILE OF userrec; { filename = gfiles\user.lst }
        bf : FILE OF boardrec; { filename = gfiles\boards.dat }
        mf : FILE OF messagerec; { filename = gfiles\ + boards[board].filename }
        mailfile : FILE OF mailrec; { filename = gfiles\email.dat }
        systatf : FILE OF systatrec; { filename = gfiles\status }
        smf : FILE OF smr; { filename = gfiles\shortmsg.dat }
        ulf : FILE OF ulrec; { filename = gfiles\uploads.dat }
        ulff : FILE OF ulfrec; { filename = gfiles\ + uboards[board].filename }
        fil : FILE OF pnr; { filename = gfiles\numbers.trm }
        vdf : FILE OF vdatar; { filename = gfiles\voting.dat }
        cf : FILE OF smr; { filename = gfiles\chat.msg }
        g : FILE OF gft; { filename = gfiles\gfiles.dat }
        fil1 : FILE OF strtype; { filename = gfiles\laston.fil - names of last 8 callers }

        sysopf : charfil; { filename = gfiles\sysop.log, and gfiles\ysysop.log - today's & yesterday's logs }
    { also other text files : gfiles\trashcan.txt - contains illegal names for aliases }
    { gfiles\user.log - log of today's callers names }
    { gfiles\votes.txt - output of voting data }
    { gfiles\bbslist.msg - list of bbs's }
    { gfiles\auto.msg - auto msg }

        { modified - TRT - 25 May 87 }
        {actual variables used by this program }
            gfilespath : strtype;
            pathdloads : strtype;
            pathmsgs : strtype;

            msgspath : packed array [0..19] of string[80];
            dloadspath : packed array [0..19] of string[80];
            tempPtr : ^integer;
            DefaultWD : integer;
            UsingHFS : boolean;

            MyPoint : Point;
            BBSrefNum : integer;
            MyTypes : SFTypeList;
            MyReply : SFReply;
            IOError : OSErr;

        fw : integer;
        slf : FILE OF slr; { filename = gfiles\seclev.dat }
        seclev : ARRAY[0..255] OF slr;

{ added - TRT - 25 May 87 }
procedure InitCommon;

var
   tempHandle : Handle;
   tempint : integer;

begin { initcommon }
   tempHandle := GetResource('STR#',StrID);
   if (ResError <> noErr) or (tempHandle = nil) then
   begin
      writeln;
      writeln('Sorry... couldn''t find the Resource STR# ID = ',StrID);
      writeln;
      writeln('Press mouse button to exit');
      repeat until button;
      exit(modifyseclev);
   end;

   for tempint := 1 to NumStrItems do
   begin { get user definable parameters from Resource file }

      case tempint of
      1 : ;
      2 : ;
      3 : begin
             GetIndString(tempstr,StrID,tempint);
             gfilespath := tempstr;
          end;
      4 : begin { modified - TRT - 20/12/86 }
             GetIndString(tempstr,StrID,tempint);
             pathdloads := tempstr;
          end;
      5 : begin
             GetIndString(tempstr,StrID,tempint);
             pathmsgs := tempstr;
          end;
      end; { cases }
   end;

   for tempint := 0 to 19 do
   { get user definable parameters from Resource file }
   begin
      GetIndString(tempstr,MsgsStrID,tempint + 1);
      if tempstr = '' then tempstr := pathmsgs;
      msgspath[tempint] := tempstr;
   end;

   for tempint := 0 to 19 do
   { get user definable parameters from Resource file }
   begin
      GetIndString(tempstr,DLoadsStrID,tempint + 1);
      if tempstr = '' then tempstr := pathdloads;
      dloadspath[tempint] := tempstr;
   end;

end; { initcommon }

BEGIN
   { don't really need these for LightSpeed Pascal }

    InitGraf(@ThePort); { Init QuickDraw }

    InitWindows;           { Init Window Manager - clear desktop & menu bar }
    InitFonts;           { Init Font Manager }
    FlushEvents(everyEvent, 0); { Throw away any stray events }
    TEInit;          { Init TextEdit }
    InitMenus;           { Init Menu Manager }
    InitDialogs(NIL);

    DrawMenuBar;

    InitCursor;

    tempPtr := pointer($3F6); { fsFCBLen }
    UsingHFS := tempPtr^ > 0;
    IOError := GetVol(@tempstr,DefaultWD);

    { added - TRT - 25 May 87 }
    writeln;
    writeln('Choose the BBS File to Get Pathnames etc from');
    writeln;

    MyPoint.h := 90; MyPoint.v := 30;
    SFGetFile(MyPoint,'',nil,-1,MyTypes,nil,MyReply);
    if MyReply.good then
    begin
       if UsingHFS then
       begin
          IOError := SetVol(nil,MyReply.vRefNum);
          if IOError <> noErr then
          begin
         writeln;
         writeln('I/O Error #',IOError,' while doing SetVol of ',MyReply.vRefNum);
         writeln;
          end;
       end;

       BBSrefNum := OpenResFile(MyReply.fName);
       if ResError <> noErr then
       begin
          writeln;
          writeln('Resource Error #',ResError,' while doing OpenResFile');
          writeln;
       end;

       { IMPORTANT - do not call other CODE segments while BBS
                     ResFile is open - it won't work! }

       InitCommon;

       if (BBSrefNum >= 0) then CloseResFile(BBSrefNum);

       if UsingHFS then
       begin
          IOError := SetVol(nil,DefaultWD);
          if IOError <> noErr then
          begin
         writeln;
         writeln('I/O Error #',IOError,' while doing SetVol of ',DefaultWD);
         writeln;
          end;
       end;


       rewrite(slf, concat(gfilespath, 'seclev.dat'));
       FOR fw := 0 TO 255 DO { these are the defaults used by the BBS for each security level }
        WITH seclev[fw] DO
            BEGIN
                anst := [];

                IF fw < 10 THEN
                    BEGIN
                        ttime := 1;
                        mallowed := 1;
                        emails := 0;
                        posts := 0;
                    END
                ELSE IF fw < 18 THEN
                    BEGIN
                        ttime := 10;
                        mallowed := 15;
                        emails := 0;
                        posts := 0;
                    END
                ELSE IF fw = 18 THEN
                    BEGIN
                        ttime := 5;
                        mallowed := 5;
                        emails := 0;
                        posts := 1;
                    END
                ELSE IF fw = 19 THEN
                    BEGIN
                        ttime := 10;
                        mallowed := 10;
                        emails := 1;
                        posts := 1;
                    END
                ELSE IF fw < 25 THEN
                    BEGIN
                        ttime := 15;
                        mallowed := 20;
                        emails := 2;
                        posts := 2;
                    END
                ELSE IF fw < 30 THEN
                    BEGIN
                        ttime := 17;
                        mallowed := 25;
                        emails := 2;
                        posts := 3;
                    END
                ELSE IF fw < 35 THEN
                    BEGIN
                        ttime := 20;
                        mallowed := 30;
                        emails := 2;
                        posts := 3;
                    END
                ELSE IF fw < 40 THEN
                    BEGIN
                        ttime := 25;
                        mallowed := 40;
                        emails := 3;
                        posts := 4;
                    END
                ELSE IF fw < 45 THEN
                    BEGIN
                        ttime := 30;
                        mallowed := 50;
                        emails := 4;
                        posts := 4;
                    END
                ELSE IF fw < 50 THEN
                    BEGIN
                        ttime := 35;
                        mallowed := 60;
                        emails := 4;
                        posts := 4;
                    END
                ELSE IF fw < 55 THEN
                    BEGIN
                        ttime := 40;
                        mallowed := 70;
                        emails := 5;
                        posts := 5;
                    END
                ELSE IF fw < 60 THEN
                    BEGIN
                        ttime := 45;
                        mallowed := 75;
                        emails := 5;
                        posts := 5;
                    END
                ELSE IF fw < 65 THEN
                    BEGIN
                        ttime := 50;
                        mallowed := 85;
                        emails := 5;
                        posts := 5;
                    END
                ELSE IF fw < 70 THEN
                    BEGIN
                        ttime := 55;
                        mallowed := 90;
                        emails := 5;
                        posts := 6;
                    END
                ELSE IF fw < 75 THEN
                    BEGIN
                        ttime := 60;
                        mallowed := 100;
                        emails := 6;
                        posts := 6;
                        anst := anst + [pana];
                    END
                ELSE IF fw < 80 THEN
                    BEGIN
                        ttime := 65;
                        mallowed := 115;
                        emails := 6;
                        posts := 6;
                        anst := anst + [pana];
                    END
                ELSE IF fw < 90 THEN
                    BEGIN
                        ttime := 65;
                        mallowed := 120;
                        emails := 6;
                        posts := 6;
                        anst := anst + [pana, sanm];
                    END
                ELSE IF fw < 95 THEN
                    BEGIN
                        ttime := 70;
                        mallowed := 150;
                        emails := 6;
                        posts := 6;
                        anst := anst + [pana, sanm, postn];
                    END
                ELSE IF fw < 99 THEN
                    BEGIN
                        ttime := 70;
                        mallowed := 200;
                        emails := 6;
                        posts := 6;
                        anst := anst + [pana, sanm, postn, emailn];
                    END
                ELSE IF fw = 99 THEN
                    BEGIN
                        ttime := 70;
                        mallowed := 200;
                        emails := 6;
                        posts := 6;
                        anst := anst + [pana, sanm, postn, emailn, lcosysop];
                    END
                ELSE IF fw = 100 THEN
                    BEGIN
                        ttime := 85;
                        mallowed := 300;
                        emails := 6;
                        posts := 6;
                        anst := anst + [pana, sanm, postn, emailn, cosysop];
                    END
                ELSE IF fw < 200 THEN
                    BEGIN
                        ttime := 90;
                        mallowed := 500;
                        emails := 6;
                        posts := 6;
                        anst := anst + [pana, sanm, postn, emailn, cosysop];
                    END
                ELSE IF fw < 255 THEN
                    BEGIN
                        ttime := 100;
                        mallowed := 1000;
                        emails := 10;
                        posts := 10;
                        anst := anst + [pana, sanm, postn, emailn, cosysop];
                    END
                ELSE
                    BEGIN { sysop }
                        ttime := 255;
                        mallowed := 32767;
                        emails := 255;
                        posts := 255;
                        anst := anst + [pana, sanm, postn, emailn, cosysop];
                    END;

                write(slf, seclev[fw]);

            END;

       close(slf);
    end;

END.